Cleaning Data With Stata

Andy Grogan-Kaylor

25 Sep 2024 10:34:12

# Background

It sometimes seems like 80% of our work as data analysts is cleaning the data, while only 20% is the actual analysis. Here are some Stata commands that are useful in cleaning data.

First we simulate some data to work with, and to clean.

# Simulate Some Data

This section is provided for illustration only, as it may be helpful to see *how* the data was simulated, and the decisions that went into simulating the data. You may also *safely ignore* this section if you like.

Show / Hide Data Simulation Code

. clear all

. set obs 100 // 100 observations
Number of observations (\_N) was 0, now 100.

. generate id = \_n // random id

. generate age = rnormal(50,10) // random generated age

. replace age = 200 in 1 // someone is 200 years old!
(1 real change made)

. generate happy = runiformint(1,5) // randomly generated happiness

. replace happy = 999 in 10 // simulate a missing value
(1 real change made)

. generate somethingelse = rnormal(0, 1) // something else!

# Look At Some Of The Data

. list in 1/10 // list first 10 observations

 ┌───────────────────────────────────┐
 │ id age happy somethi~e │
 ├───────────────────────────────────┤
 1. │ 1 200 5 -.2740025 │
 2. │ 2 41.74908 1 .3407284 │
 3. │ 3 48.99197 1 1.097281 │
 4. │ 4 41.29318 2 .99441 │
 5. │ 5 38.30437 1 -.9095201 │
 ├───────────────────────────────────┤
 6. │ 6 65.80429 3 -.6050416 │
 7. │ 7 44.24375 2 .0133314 │
 8. │ 8 52.14927 5 .4847669 │
 9. │ 9 54.0201 5 -.9933645 │
 10. │ 10 67.752 999 .5900007 │
 └───────────────────────────────────┘

# Clean The Data!

## Look at The Data and Think About The Data (describe, summarize, tabulate, codebook, browse)

When we look at variables we are looking for values that don’t make sense, or that are outside the plausible range. As we are working with the data, it may sometimes be helpful to browse the data.

. describe // describe the data

Contains data
 Observations: 100
 Variables: 4
───────────────────────────────────────────────────────────────────────────────────────────
Variable Storage Display Value
 name type format label Variable label
───────────────────────────────────────────────────────────────────────────────────────────
id float %9.0g
age float %9.0g
happy float %9.0g
somethingelse float %9.0g
───────────────────────────────────────────────────────────────────────────────────────────
Sorted by:
 Note: Dataset has changed since last saved.

. summarize // descriptive statistics

 Variable │ Obs Mean Std. dev. Min Max
─────────────┼─────────────────────────────────────────────────────────
 id │ 100 50.5 29.01149 1 100
 age │ 100 51.58624 18.05763 24.2431 200
 happy │ 100 12.94 99.61267 1 999
somethinge~e │ 100 -.0249813 1.009199 -2.277072 2.547337

. tabulate happy // tabulation of this particular categorical variable

 happy │ Freq. Percent Cum.
────────────┼───────────────────────────────────
 1 │ 20 20.00 20.00
 2 │ 24 24.00 44.00
 3 │ 15 15.00 59.00
 4 │ 18 18.00 77.00
 5 │ 22 22.00 99.00
 999 │ 1 1.00 100.00
────────────┼───────────────────────────────────
 Total │ 100 100.00

. codebook happy // VERY detailed view of this particular categorical variable

───────────────────────────────────────────────────────────────────────────────────────────
happy (unlabeled)
───────────────────────────────────────────────────────────────────────────────────────────

 Type: Numeric (float)

 Range: [1,999] Units: 1
 Unique values: 6 Missing .: 0/100

 Tabulation: Freq. Value
 20 1
 24 2
 15 3
 18 4
 22 5
 1 999

Notice that…

* There are variables in which we may not have interest.
* None of the variables are labelled informatively.
* Variables do not seem to have informative value labels.
* Someone appears to 200 years old.
* There appear to be missing values in the variable happy that need to be recoded.

Remember that the command lookfor is often very helpful in *looking for* a particular variable. e.g. lookfor happy.

## Only keep The Variables Of Interest

We may only be interested in keeping some variables to keep our analytic data set more manageable.

For this particular analysis we may wish to drop the variable called somethingelse.

. keep id age happy // keep only relevant variables

We could also have said drop somethingelse.

## Add *Variable* Labels (label variable "...")

. label variable id "ID" // label variable

. label variable age "Age in Years" // label variable

. label variable happy "Happiness Scale" // label variable

## Create *Value* Labels (label define ...)

. label define happy 1 "Rarely" 2 "Sometimes" 3 "Often" 4 "Always" // create value label

## Attach *Value* Labels To *Variables* (label values ...)

*Variables* and *value labels* can have the same names but are different things. We add the variable label happy to the variable named happy.

. label values happy happy // attach VALUE LABEL happy to VARIABLE happy

## Recode Outliers, Values That Are Errors, Or Values That Should Be Coded As Missing (recode)

. recode happy (999 = .) // recode values as missing
(1 changes made to happy)

. recode age (100/max = 100) // age is topcoded at 100 (may or may not be plausible)
(1 changes made to age)

# We describe and summarize The Data And See The Changes That Have Been Made

. describe

Contains data
 Observations: 100
 Variables: 3
───────────────────────────────────────────────────────────────────────────────────────────
Variable Storage Display Value
 name type format label Variable label
───────────────────────────────────────────────────────────────────────────────────────────
id float %9.0g ID
age float %9.0g Age in Years
happy float %9.0g happy Happiness Scale
───────────────────────────────────────────────────────────────────────────────────────────
Sorted by:
 Note: Dataset has changed since last saved.

. summarize

 Variable │ Obs Mean Std. dev. Min Max
─────────────┼─────────────────────────────────────────────────────────
 id │ 100 50.5 29.01149 1 100
 age │ 100 50.58624 11.2362 24.2431 100
 happy │ 99 2.979798 1.463709 1 5